;redcode-94nop
;name Mythos
;author S.Fernandes
;strategy hydra/paper
;strategy paper from Neith
;strategy hydra from Nemesis
;assert CORESIZE == 8000

        org     qscan

MARK    equ     <300
mloc    equ     5000
ploc    equ     7352

warr    spl     1           ,    MARK*4
        spl     1           ,    MARK*5
        spl     1           ,    MARK*6
        mov     {micro      ,    {mboot
mboot   spl     mloc        ,    MARK*7
        mov     <papera     ,    {pboot
pboot   djn.f   ploc        ,    MARK*8

stepa   equ     4288
stepb   equ     2102
X       equ     4503 
Y       equ     2465

papera  spl     stepa       ,    8
        mov     >papera     ,    }papera
paperb  spl     stepb       ,    <mid
        mov     >mid        ,    }paperb
        mov     bomb        ,    >X
        mov     bomb        ,    }Y
mid     jmz.f   paperb      ,    paperb+8
bomb    dat     <2667       ,    <5334

first   equ     1692
step    equ     4098

micro   spl    #8           ,    <spr
        mov.i  #1           ,    <spr
spr     mov    dec          ,    first
        add    #step        ,    spr
        mov    micro        ,    @spr
        djn.f  @spr         ,    <3684
        dat    0            ,    0
dec     djn    -2           ,    #99

        for     47
        dat     0           ,    0
        rof

        qfac   equ 7491
        qdec   equ 5612

        qa     equ (qfac*(qtab0-1-qptr)+1)
        qb     equ (qfac*(qtab0-qptr)+1)
        qc     equ (qfac*(qtab1-1-qptr)+1)
        qd     equ (qfac*(qtab1-qptr)+1)
        qe     equ (qfac*(qtab1+1-qptr)+1)
        qf     equ (qfac*(qtab2-qptr)+1)

        qtime  equ 18
        qstep  equ -7
        qgap   equ 87

qdecode mul.b  *q1,          qptr
q0      sne    <qtab0,       @qptr
q1      add.b  qtab1,        qptr
q2      mov    qtab2,        @qptr
qptr    mov    qtab2,        *qdec
        add    #qstep,       qptr
        djn    q2,           #qtime
        jmp    warr,         qc
qtab1   dat    4000,         qd
        dat    4000,         qe

qscan   sne    qptr+qdec*qe, qptr+qdec*qe+qe
        seq    <qtab1+1,     qptr+qdec*(qe-1)+qe-1
        jmp    qdecode,      }q1
        sne    qptr+qdec*qb, qptr+qdec*qb+qd
        seq    <qtab0,       qptr+qdec*(qb-1)+qd
        jmp    qdecode,      {qdecode
        sne    qptr+qdec*qa, qptr+qdec*qa+qd
        seq    <qtab0-1,     qptr+qdec*(qa-1)+qd
        djn.a  qdecode,      {qdecode
        sne    qptr+qdec*qf, qptr+qdec*qf+qd
        seq    <qtab2,       qptr+qdec*(qf-1)+qd
        jmp    qdecode,      }qdecode
        sne    qptr+qdec*qc, qptr+qdec*qc+qc
        seq    <qtab1-1,     qptr+qdec*(qc-1)+qc-1
        jmp    qdecode,      {q1
        sne    qptr+qdec*qd, qptr+qdec*qd+qd
        seq    <qtab1,       qptr+qdec*(qd-1)+qd-1
        jmp    qdecode,      qa
qtab0   jmp    warr,         qb
qtab2   dat    qgap,         qf
        end